Laboratory 6 - Theory

Instructions working on strings of bytes/words/doublewords

String operations

Instructions working on strings have default operands (parameters).

Types of string instructions:

which use a source string and a destination string (MOVSB, MOVSW, MOVSD, CMPSB, CMPSW, CMPSD)
which use only a source string (LODSB, LODSW, LODSD)
which use only a destination string (STOSB, STOSW, STOSD, SCASB, SCASW, SCASD)

You will remember them more easily:)

Move String = MOVS
Compare String = CMPS
Load String = LODS
Store String = STOS
Scan String = SCAS

A string is characterized by:

the type of the elements(bytes or words) => is given by the last letter of the instruction that is used (B=byte, W=word, D=doubleword), both strings having the same type
the address of the first element => is a FAR memory address which is memorised in:
- in DS:ESI - for the source string
- in ES:EDI - for the destination string
the parsing direction => is given by the value of the DF flag (0 - from small addresses to large addresses, 1 - from large addresses to small addresses.)
the number of elements => when needed is placed in CX or ECX

Instructions for data transfer

LODSB	The byte from the address <DS:ESI> is loaded in AL If DF=0 then inc(ESI), else dec(ESI)
LODSW	The word from the address <DS:ESI> is loaded in AX f DF=0 then ESI:=ESI+2, else ESI:=ESI-2
LODSD	The double word from the address <DS:ESI> is loaded in EAX If DF=0 then ESI:=ESI+4, else ESI:=ESI-4
STOSB	Store AL into the byte from the address <ES:EDI> If DF=0 then inc(EDI), else dec(EDI)
STOSW	Store AX into the word from the address <ES:EDI> If DF=0 then EDI:= EDI+2, else EDI:= EDI-2
STOSD	Store EAX into the double word from the address <ES:EDI> If DF=0 then EDI:= EDI+4, else EDI:= EDI-4
MOVSB	Store the byte from the address <DS:ESI> to the address <ES:EDI> If DF=0 then inc(SI), inc(DI), else dec(SI), dec(DI)
MOVSW	Store the word from the address <DS:ESI> to the address <ES:EDI> If DF=0 then ESI:= ESI+2, EDI:= EDI+2, else ESI:= ESI-2, EDI:= EDI-2
MOVSD	Store the double word from the address <DS:ESI> to the address <ES:EDI> If DF=0 then ESI:= ESI+4, EDI:= EDI+4, else ESI:= ESI-4, EDI:= EDI-4

Obs. Considering the use of the flat memory model, at any start of the program execution, the OS will initialize with the same value the segment registers DS = ES. The programmer has no responsibility in what concerns loading / updating / modifying these values. In the source code that uses the instructions on strings the programmer will only need to manage the offset of these strings.

Example:

;We have a source string of words. Copy this string into another string. We assume we know the length of this string.
mov ECX, dim_sir ; no of elements in string
mov ESI, sir_sursa ; load offset sir_sursa in ESI
mov EDI, sir_dest ; load offset sir_dest in EDI
CLD
Again:
	LODSW
	STOSW
LOOP Again

Considering that LODS + STOS = MOVS the above loop is equivalent to:

Again:
MOVSW
LOOP Again

or (see the prefix instruction section below)

rep MOVSW

Instructions for data consultation and comparison

SCASB	CMP AL, <ES:EDI> If DF=0 Then inc(EDI), Else dec(EDI)
SCASW	CMP AX, <ES:EDI> If DF=0 Then EDI:= EDI+2, Else EDI:= EDI-2
SCASD	CMP EAX, <ES:EDI> If DF=0 Then EDI:= EDI+4, Else EDI:= EDI-4
CMPSB	CMP <DS:ESI>, <ES:EDI> If DF=0 Then inc(ESI), inc(EDI), Else dec(ESI), dec(EDI)
CMPSW	CMP <DS:ESI>, <ES:EDI> If DF=0 Then ESI:= ESI+2, EDI:= EDI+2, Else ESI:= ESI-2, EDI:= EDI-2
CMPSD	CMP <DS:ESI>, <ES:EDI> If DF=0 Then ESI:= ESI+4, EDI:= EDI+4, Else ESI:= ESI-4, EDI:= EDI-4

Example:

;A sequence of bytes is given. Find the last character "0".
;... all data about the "destination" string is loaded
MOV AL, '0'
MOV ECX, lung_sir
STD
Cont_caut: ;continue search...
	SCASB
	JE Found
LOOP Cont_caut
;...
Found:
	INC EDI;I return to the character found before EDI was decremented

Prefix instructions for the repetitive execution of a string instruction

repetitive_prefix string_instruction

equivalent to

Again:
	string_instruction 
LOOP Again

where repetitive_prefix can be REP, equivalent to REPE (Repeat While Equal), REPZ (Repeat While Zero) - which repeat the execution of instructions SCAS or CMPS until ECX becomes 0 or an unmatch occurs ( => ZF=0)
or it can be REPNE (Repeat While Not Equal) or REPNZ (Repeat While Not Zero) - which repeat the execution of instructions SCAS or CMPS until ECX becomes 0 or when a match occurs ( => ZF=1)

Observations:

string instructions don not change the flags as a result of modifications to ESI, EDI or ECX
LODS, STOS, MOVS - do not change any flag, while SCAS and CMPS change the flags because they compare data.